主題: [教學]用windows shell建立程式的桌面捷徑 [打印本頁]

---

發表人: yjmg    時間: 2007-3-28 11:17 PM     主題: [教學]用windows shell建立程式的桌面捷徑

引用 "用WSH建立桌面捷徑":

Windows Script Host 以及 Windows Shell是Windows 系統兩大指令執行管理物件。待會，我們就會透過建立這兩個物件的方式，逐步建立桌面捷徑。

以下為程式碼：


'設定桌面目錄的16進位碼
const DESKTOP = &H0&

'建立WSH & Windows Shell物件
'------------------------------------------
set oWSHShell = CreateObject("Wscript.shell")
set oShell = CreateObject("Shell.Application")

'利用Shell物件取得桌面目錄路徑
'------------------------------------------
set oFolder = oShell.Namespace(DESKTOP) '這裡會利用Namespace方法取得Folder物件，但我們需要FolderItem以取得目錄路徑
set oFolderItem = oFolder.Self '取得FolderItem目錄
DeskTopPath = oFolderItem.Path '取得桌面路徑

'設定捷徑相關資訊
'------------------------------------------
ShortCutName = "MyProgram" '設定捷徑名稱
ShortCutPath = "C:＼MyFolderMyProgram.exe" '設定捷徑目錄，就是目標目錄
WorkingPath = "C:＼MyFolder" '設定工作目錄，就是開始位置

'建立捷徑
'------------------------------------------
set oShortCut = oWSHShell.CreateShortCut _
(DeskTopPath & "＼" & ShortCutName & ".lnk") '建立桌面捷徑檔
oShortCut.TargetPath = ShortCutPath '設定該捷徑的目標
oShortCut.WorkingDirectory = WorkingPath '設定該捷徑的開始位置
oShortCut.Save '儲存物件，這步驟才會真正建立捷徑

接下來我們把以上的程式把存成ShortCutMaker.vbs，剩下的步驟就很簡單了。

最後的步驟，就是我們只要寫個批次檔，把XCOPY跟剛剛寫的vbs兜在一塊，簡易安裝檔就完成嚕。請參考以下檔案：

MyInstall.bat內容：

XCOPY "＼＼RemoteComputer＼Install Folder＼" "C:＼MyProgram" /s /e
ShortCutMaker.vbs

呵呵，這樣花心血Code的系統就看起來比較有價值一點了啦...^^".....

p.s1 請原諒我把反斜線變成全形的反斜線，不然文章會過濾掉，我沒解法.....請大家想像一下那其實是半形的黑...

p.s2 關於捷徑建立的參考資訊請見下方資訊：

WSH 建立捷徑法
http://www.microsoft.com/taiwan/ ... /may05/hey0509.mspx
各系統目錄16位元代碼
http://www.openitpower.com/wenzhang/117/11946_1.html

---

歡迎光臨 TWed2k (http://twed2k.org/)

Powered by Discuz! 4.1.0